Lajos Joo wrote:
I am using xmlspy for testing with the built in xslt engine which said that it
is not a node item.
And in java:
Exception dropped during XSLT transformation: net.sf.saxon.trans.DynamicError:
Required item type of second operand of 'intersect' is node(); supplied value
has item type xs:string
I can see that happening when your complete XML has more than those
'par' element and that way the template is applied without passing in a
value for the parameter.
In that case it might be better to introduce a mode to process those
descendants of 'par' elements e.g.
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
version="2.0"
xmlns:xsd="http://www.w3.org/2001/XMLSchema";
exclude-result-prefixes="xsd">
<xsl:output indent="yes"/>
<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@*, node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="node()" mode="m1">
<xsl:param name="cn"/>
<xsl:if test="descendant-or-self::node() intersect $cn">
<xsl:copy>
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="node()" mode="m1">
<xsl:with-param name="cn" select="$cn"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:if>
</xsl:template>
<xsl:template match="par">
<xsl:variable name="p" as="element()" select="."/>
<xsl:for-each-group select="descendant::node()"
group-ending-with="linebreak">
<xsl:variable name="lb" as="element()?"
select="current-group()[self::linebreak]"/>
<par>
<xsl:apply-templates select="$p/@*"/>
<xsl:apply-templates
select="$p/node()[descendant-or-self::node() intersect (current-group()
except $lb)]" mode="m1">
<xsl:with-param name="cn" select="current-group() except $lb"/>
</xsl:apply-templates>
</par>
</xsl:for-each-group>
</xsl:template>
</xsl:stylesheet>
--
Martin Honnen
http://msmvps.com/blogs/martin_honnen/
--~------------------------------------------------------------------
XSL-List info and archive: http://www.mulberrytech.com/xsl/xsl-list
To unsubscribe, go to: http://lists.mulberrytech.com/xsl-list/
or e-mail: <mailto:xsl-list-unsubscribe(_at_)lists(_dot_)mulberrytech(_dot_)com>
--~--