xsl-list
[Top] [All Lists]

Re: [xsl] Does <xsl:copy> use a lot of memory? Is there an alternative that is more efficient?

2012-09-03 10:58:41
I suspect Michael just posted something equivalent or better or whatever but

<x>
   <b id="i1">aaa</b>
   <b idref="i1"/>
   <b id="i2">kkk <c idref="i3"/></b>
   <b> aaa <c idref="i2"/></b>
   <b id="i3"> aaa <c idref="i2"/></b>
</x>

processed with

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform";>

<xsl:key name="id" match="*[@id]" use="@id"/>

<xsl:template match="*">
<xsl:copy>
<xsl:copy-of select="@* except @idref"/>
<xsl:apply-templates select="@idref,node()"/>
</xsl:copy>
</xsl:template>

<xsl:template match="@idref">
<xsl:param name="seen" tunnel="yes"/>
<xsl:choose>
<xsl:when test=".=$seen"><xsl:copy-of select="."/>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="key('id',.)">
<xsl:with-param name="seen" select="$seen,string(.)" tunnel="yes"/>
</xsl:apply-templates>
</xsl:otherwise>
</xsl:choose>
</xsl:template>


</xsl:stylesheet>


produces




$ saxon9 aaa.xml aaa.xsl
<?xml version="1.0" encoding="UTF-8"?><x>
   <b id="i1">aaa</b>
   <b><b id="i1">aaa</b></b>
<b id="i2">kkk <c><b id="i3"> aaa <c><b id="i2">kkk <c idref="i3"/></b></c></b></c></b> <b> aaa <c><b id="i2">kkk <c><b id="i3"> aaa <c idref="i2"/></b></c></b></c></b> <b id="i3"> aaa <c><b id="i2">kkk <c><b id="i3"> aaa <c idref="i2"/></b></c></b></c></b>
</x>



where idrefs have been expanded out unless you are already in the the descendants of its expansion in which case it is left as a ref.

David


________________________________________________________________________
The Numerical Algorithms Group Ltd is a company registered in England
and Wales with company number 1249803. The registered office is:
Wilkinson House, Jordan Hill Road, Oxford OX2 8DR, United Kingdom.

This e-mail has been scanned for all viruses by Star. The service is
powered by MessageLabs. ________________________________________________________________________

--~------------------------------------------------------------------
XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list
To unsubscribe, go to: http://lists.mulberrytech.com/xsl-list/
or e-mail: <mailto:xsl-list-unsubscribe(_at_)lists(_dot_)mulberrytech(_dot_)com>
--~--